Add structured production logging (#105, #107) (#141)

* Update README.md

* Add structured JSON production logging (#105)

* Log requests and background failures (#107)

* Document production logging and the VPS runbook
This commit is contained in:
2026-11-10 22:00:05 +01:00
committed by GitHub
parent f8897fa5ae
commit 202b9b1f6a
20 changed files with 1380 additions and 15 deletions
+47
View File
@@ -0,0 +1,47 @@
defmodule ChesstrainerWeb.RequestIdTest do
use ExUnit.Case, async: false
import Plug.Conn
alias ChesstrainerWeb.Plugs.PutRequestId
alias ChesstrainerWeb.UserAuth
setup do
on_exit(fn -> Logger.metadata(request_id: nil) end)
end
test "PutRequestId copies the request id into the session" do
conn =
:get
|> Phoenix.ConnTest.build_conn("/")
|> Phoenix.ConnTest.init_test_session(%{})
|> assign(:request_id, "request-1")
|> PutRequestId.call([])
assert get_session(conn, :request_id) == "request-1"
end
test "PutRequestId leaves the session alone without a request id" do
conn =
:get
|> Phoenix.ConnTest.build_conn("/")
|> Phoenix.ConnTest.init_test_session(%{})
|> PutRequestId.call([])
assert get_session(conn, :request_id) == nil
end
test "mounting a LiveView puts the session's request id into logger metadata" do
socket = %Phoenix.LiveView.Socket{}
assert {:cont, _socket} =
UserAuth.on_mount(
:mount_current_scope,
%{},
%{"request_id" => "request-2", "user_token" => nil},
socket
)
assert Logger.metadata()[:request_id] == "request-2"
end
end
@@ -0,0 +1,97 @@
defmodule ChesstrainerWeb.RequestLoggerTest do
use ChesstrainerWeb.ConnCase, async: false
import ExUnit.CaptureLog
import Plug.Conn
alias ChesstrainerWeb.RequestLogger
setup do
level = Logger.level()
Logger.configure(level: :info)
on_exit(fn -> Logger.configure(level: level) end)
:ok
end
describe "handle_event/4" do
test "logs one access line with method, path, status, duration and request id" do
conn = access_conn("GET", "/endgames", 200, "request-1")
log =
capture_log([level: :info], fn ->
RequestLogger.handle_event(
[:phoenix, :endpoint, :stop],
%{duration: 12_500_000},
%{conn: conn},
:ok
)
end)
assert log =~ "GET /endgames 200 in 12.5ms"
assert log =~ "request_id=request-1"
end
test "redacts token-like path segments" do
token = "SFMyNTY." <> String.duplicate("a", 43)
conn = access_conn("GET", "/users/reset-password/#{token}", 200, "request-1")
log =
capture_log([level: :info], fn ->
RequestLogger.handle_event(
[:phoenix, :endpoint, :stop],
%{duration: 1_000_000},
%{conn: conn},
:ok
)
end)
assert log =~ "GET /users/reset-password/[REDACTED] 200 in 1.0ms"
refute log =~ token
end
test "never logs the query string" do
conn =
:get
|> build_conn("/endgames?email=user@example.com&secret=abc")
|> assign(:request_id, "request-1")
|> put_status(200)
log =
capture_log([level: :info], fn ->
RequestLogger.handle_event(
[:phoenix, :endpoint, :stop],
%{duration: 1_000_000},
%{conn: conn},
:ok
)
end)
assert log =~ "GET /endgames 200 in 1.0ms"
refute log =~ "user@example.com"
refute log =~ "secret=abc"
end
end
describe "endpoint integration" do
test "emits exactly one access line for a request", %{conn: conn} do
log = capture_log([level: :info], fn -> get(conn, ~p"/health") end)
assert length(Regex.scan(~r/GET \/health 200 in [\d.]+ms/, log)) == 1
assert log =~ "request_id="
end
test "emits an access line for a LiveView initial request", %{conn: conn} do
log = capture_log([level: :info], fn -> get(conn, ~p"/users/log-in") end)
assert length(Regex.scan(~r/GET \/users\/log-in 200 in [\d.]+ms/, log)) == 1
assert log =~ "request_id="
end
end
defp access_conn(method, path, status, request_id) do
method
|> build_conn(path)
|> assign(:request_id, request_id)
|> put_status(status)
end
end